@echo off
setlocal EnableExtensions EnableDelayedExpansion

set "REN_DIR=%~dp0"
for %%I in ("%REN_DIR%..") do set "PROJ_ROOT=%%~fI"

set "CONFIG_DIR=%PROJ_ROOT%\.config"
set "CONFIG_PATH=%CONFIG_DIR%\config.json"
set "GET_STRUCT_DIR=%CONFIG_DIR%\GetStructDir.ps1"

if not exist "%CONFIG_PATH%" (
    echo [ERROR] config.json not found at %CONFIG_PATH%
    echo Please run ConfigLoader.ps1 to deploy helper files.
    exit /b 1
)

if not exist "%GET_STRUCT_DIR%" (
    echo [ERROR] GetStructDir.ps1 not found at %GET_STRUCT_DIR%
    echo Please run ConfigLoader.ps1 to deploy helper files.
    exit /b 1
)

for /f "usebackq delims=" %%I in (`powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "Set-StrictMode -Version Latest; $structDir = & '%GET_STRUCT_DIR%' -ProjectRoot '%PROJ_ROOT%'; if (-not $structDir) { throw \"Failed to get structDir from GetStructDir.ps1\" }; $pyPath = Join-Path $structDir 'zip_sequences.py'; if (-not (Test-Path -LiteralPath $pyPath)) { throw \"zip_sequences.py not found at $pyPath\" }; Write-Output $pyPath"`) do set "PY_SCRIPT=%%~I"

if not defined PY_SCRIPT (
    echo [ERROR] Unable to resolve zip_sequences.py path from config.
    exit /b 1
)

pushd "%PROJ_ROOT%" >nul 2>&1

python "%PY_SCRIPT%" --verbose %*
set "ERR=!ERRORLEVEL!"

popd >nul 2>&1

if !ERR! NEQ 0 (
    echo Failed to update render sequence archives ^(exit code !ERR!^).
    exit /b !ERR!
)

exit /b 0

